TOP > カテゴリ > ロボット・電子工作・マイコン >

スマホでLEDを点灯させる (Webサーバー版)

今回はESP-WROOM-02にArduinoスケッチを書き込み、Arduino互換機として使用します。ステーションモードでWifi接続をして、そのIPアドレスを使用してWebサーバーを起動します。

※WebサーバーはESP-WROOM-02の標準機能です。

ESP-WROOM-02がはじめての方はデータを送受信をするIoTデバイスの作り方 [ESP-WROOM-02版]を先にご覧ください。

ArduinoからESP-WROOM-02を使用する場合はスマホでLEDを点灯させる (クライアント版)をご覧ください。

システムの概要

ESP-WROOM-02のWebサーバーを起動して、スマートフォンでそのURLにアクセスします。スマホから直にマイコンボード(ESP-WROOM-02)にアクセスできますので、リアルタイムでLEDの切り替えを行う事が可能です。

※IPアドレスは各自の環境に合わせてください。
※スマホの回線はWebサーバーと同じ環境にして下さい。

スケッチ(プログラム)

ESP-WROOM-02のIO5(5)を使用してLEDを点灯させます。
※SSID、PASSWORD、IP情報は各自の環境に合わせてください。

#include <ESP8266WiFi.h>
#include <WiFiClient.h>
#include <ESP8266WebServer.h>
#include <ESP8266mDNS.h>

const char* ssid     = "xxx";
const char* password = "xxx";

// 文字列ではなく、数値配列です。
IPAddress ip(192, 168, 1, 33);
IPAddress gateway(192, 168, 1, 1);
IPAddress netmask(255, 255, 255, 0);

const int PIN_LED = 5;
String html = "";

ESP8266WebServer server(80);

void setup(void){
  html = "<!DOCTYPE html>\
<html>\
<head>\
<meta charset=\"UTF-8\">\
<meta name=\"viewport\" content=\"width=device-width,initial-scale=1,minimum-scale=1\">\
</head>\
<body>\
<br>\
<br>\
<br>\
<input type=\"button\" value=\"オン\" style=\"font-size:32px;\" onclick=\"location.href='/led-ON';\">&nbsp;&nbsp;&nbsp;\
<input type=\"button\" value=\"オフ\" style=\"font-size:32px;\" onclick=\"location.href='/led-OFF';\">\
</body>\
</html>";

  pinMode(PIN_LED, OUTPUT);
  digitalWrite(PIN_LED, LOW);

  Serial.begin(115200);

  // WIFI_AP, WIFI_STA, WIFI_AP_STA or WIFI_OFF
  WiFi.mode(WIFI_STA);
  WiFi.config(ip, gateway,netmask);    
  WiFi.begin(ssid, password);
  Serial.println("");

  // Wifi接続ができるまで待機
  while (WiFi.status() != WL_CONNECTED) {
    delay(500);
    Serial.print(".");
  }
  Serial.println("");
  Serial.print("IPアドレス: ");
  Serial.println(WiFi.localIP());
  
  // ローカルネットワーク内のみ有効のmDNS(マルチキャストDNS)を開始
  // bool MDNSResponder::begin(const char* hostname){}
  if (MDNS.begin("petitmonte")) {
    Serial.println("mDNSレスポンダーの開始");
  }

  // トップページ
  server.on("/", [](){
    // HTTPステータスコード(200) リクエストの成功
    server.send(200, "text/html", html);     
  });
  
  // LEDをオン
  server.on("/led-ON", [](){
    digitalWrite(PIN_LED, HIGH);
    // HTTPステータスコード(200) リクエストの成功
    server.send(200, "text/html", html);      
  });

  // LEDをオフ
  server.on("/led-OFF", [](){
    digitalWrite(PIN_LED, LOW);
    // HTTPステータスコード(200) リクエストの成功
    server.send(200, "text/html", html);      
  });

  // 存在しないURLを指定した場合の動作を指定する
  server.onNotFound([](){
    // HTTPステータスコード(404) 未検出(存在しないファイルにアクセス)  
    server.send(404, "text/plain", "404");
  });

  server.begin();
  Serial.println("Webサーバーの開始");
}

void loop(void){  
  // Webサーバの接続要求待ち
  server.handleClient();
}

ブラウザで http://192.168.1.33/ にアクセスしてボタンを押すだけです。





関連記事



公開日:2017年04月16日 最終更新日:2017年05月05日
記事NO:02329