VBAでPDFファイルのページを分割(抽出)する[ExcelのTIPS]

' PDFDesigner Tools API
Public Declare Function LoadPDF Lib "pdftool.dll" (ByVal OpenFileName As String) As Long
Public Declare Sub FreePDF Lib "pdftool.dll" (ByVal PDF As Long)

Public Declare Function CutPDF Lib "pdftool.dll" (ByVal PDF As Long, ByVal StartPos As Long, ByVal EndPos As Long, ByVal SaveFileName As String) As Long

' PDFのバージョンを1.4形式にする(コピーしたファイルを編集)
Public Sub ChangePDFVersion(ByVal OpenFileName As String, ByVal SaveFileName As String)
  Dim Stream() As Byte  ' ストリーム
  Dim FileNo As Integer ' ファイルNO

  ' ファイルを読み込む
  FileNo = FreeFile
  ReDim Stream(FileLen(OpenFileName) - 1)

  Open OpenFileName For Binary As #FileNo
    Get #FileNo, , Stream
  Close #FileNo

  ' PDFの形式を1.4にする
  Stream(5) = "&H31":   Stream(7) = "&H34"

  ' ファイルの出力
  FileNo = FreeFile
  Open SaveFileName For Binary Access Write As #FileNo
    Put #FileNo, , Stream
  Close #FileNo
End Sub

' PDFファイルを抽出する
'  StartPos: 開始ページ
'  EndPos  : 終了ページ
'  戻り値  : 1:成功 -1:失敗
'  備考    : PDFのページ数はGetPDFPageCount()APIで取得可能。詳細は公式サイト参照。
'            ※PDFファイルはChangePDFVersion関数で1.4形式にする必要があります。
Public Function vba_CutPDF(ByVal PDF As String, ByVal StartPos As Long, ByVal EndPos As Long, ByVal SaveFileName As String) As Long
  Dim p As Long
  Dim tmp As String
  Dim Result As Long
  
  ' 拡張子をtmpに変換する
  tmp = Replace(PDF, ".pdf", ".tmp", compare:=vbTextCompare)
  
  ' 元のPDFファイルをコピーしてバージョンを1.4形式に変更する
  Call ChangePDFVersion(PDF, tmp)
  
  ' PDFファイルを読み込んでハンドルを取得する
  p = LoadPDF(tmp)
 
  ' PDFファイルのページを抽出する
  Result = CutPDF(p, StartPos, EndPos, SaveFileName)
 
  ' PDFファイルのハンドルを解放する
  FreePDF (p)
  
  ' テンポラリファイルを削除する
  Kill (tmp)
  
  vba_CutPDF = Result
End Function

Private Sub CommandButton1_Click()
  ' カレントディレクトリをExcelファイルとpdftool.dllがある場所に変更
  ChDir ThisWorkbook.Path
  ' 最初の1ページを抽出する
  call vba_CutPDF("C:\対象.pdf", 1, 1, "C:\結果.pdf")
End Sub