TOP > カテゴリ > Visual Basic >

音楽、動画プレビュー付き「ファイルを開く」ダイアログを表示する

音楽、動画プレビュー付き「ファイルを開く」ダイアログを表示するサンプルです。

サンプルの実行画面

APIの宣言

[OpenDlgPw.bas]

'--------------------------------------------------------------------------
'音楽、動画プレビュー機能付き「ファイルを開く」コモンダイヤログを表示するAPI関数
'--------------------------------------------------------------------------
'
'<引数>  pOpenfilename:OPENFILENAME
'<戻り値> OKボタンを押した時1、キャンセルボタンを押した時0
Public Declare Function GetOpenFileNamePreview Lib "msvfw32.dll" Alias "GetOpenFileNamePreviewA" (pOpenfilename As OPENFILENAME) As Long

'OPENFILENAME構造体
Public Type OPENFILENAME
    lStructSize As Long             '構造体のサイズ
    hwndOwner As Long               'ウインドウのハンドル
    hInstance As Long               'インスタンスハンドル
    lpstrFilter As String           'フィルター
    lpstrCustomFilter As String     'カスタムフィルター
    nMaxCustFilter As Long          'カスタムフィルターのサイズ
    nFilterIndex As Long            'フィルタのインデックス
    lpstrFile As String             'ファイル名のバッファ
    nMaxFile As Long                'ファイル名のバッファのサイズ
    lpstrFileTitle As String        'フルパス用のバッファ
    nMaxFileTitle As Long           'フルパス用のバッファのサイズ
    lpstrInitialDir As String       'ディレクトリを指定
    lpstrTitle As String            'ダイヤログボックスのタイトル
    flags As Long                   '定数(OFN_××参照)
    nFileOffset As Integer          'フルパスの中のファイル名までのオフセット
    nFileExtension As Integer       '拡張子までのオフセット
    lpstrDefExt As String           'デフォルトの拡張子
    lCustData As Long               'lpfnHookで渡すデータ
    lpfnHook As Long                'フック関数のポインタ
    lpTemplateName As String        'テンプレート名
End Type


Public Const OFN_ALLOWMULTISELECT = &H200       '複数ファイルを選択可能にする
Public Const OFN_CREATEPROMPT = &H2000          '指定のファイル名が存在しない時にメッセージボックスを表示
Public Const OFN_FILEMUSTEXIST = &H1000         '存在しないファイル名は入力不可
Public Const OFN_HIDEREADONLY = &H4             '読み取り専用のチェックボックスを非表示
Public Const OFN_NOCHANGEDIR = &H8              '他のサブディレクトリから選択不可
Public Const OFN_NOREADONLYRETURN = &H8000      '読み込み専用ファイルと書きこみ禁止ディレクトリの選択不可
Public Const OFN_NOVALIDATE = &H100             'ファイル名の有効性をチェックしない
Public Const OFN_OVERWRITEPROMPT = &H2          '既存のファイル名を指定した時にメッセージを出す
Public Const OFN_PATHMUSTEXIST = &H800          '有効なパスだけをうけつける
Public Const OFN_READONLY = &H1                 '読み取り専用のチェックボックスをチェック
Public Const OFN_SHOWHELP = &H10                'ヘルプボタンを表示
        
'-----------------------------------------------------------------------------------
'■関数名       OpenPreviewDlg
'■用途         音楽、動画プレビュー機能付き「ファイルを開く」コモンダイヤログを表示する
'■引数         nHandle:ウインドウのハンドル、nFilter:フィルター
'■戻り値       ファイルを選択した場合そのファイルのパス名、キャンセルを押した場合""が戻る
'-----------------------------------------------------------------------------------
Public Function OpenPreviewDlg(nHandle As Long, nFilter As String) As String

  Dim OFN As OPENFILENAME                   'OPENFILENAME構造体
  Dim Ret As Long                           '戻り値

   With OFN                                 '構造体の設定
      .flags = OFN_PATHMUSTEXIST Or _
               OFN_FILEMUSTEXIST Or _
               OFN_HIDEREADONLY Or _
               OFN_OVERWRITEPROMPT
              'Or OFN_SHOWHELP
      .hInstance = App.hInstance            'インスタンスハンドルを設定
      .hwndOwner = nHandle                  'ウインドウハンドルを設定
      .lpstrTitle = "ファイルを開く"         'タイトルを設定
      .lpstrFilter = nFilter                'フィルターを設定
      .lStructSize = Len(OFN)               '構造体のサイズを設定
      .nMaxFile = 250                       'ファイル名のバッファサイズを設定
      .lpstrFileTitle = String(250, Chr(0)) 'フルパス用のバッファを確保
      .nMaxFileTitle = 250                  'フルパス用のバッファサイズを設定
      .lpstrFile = String(250, Chr(0))      'ファイル名のバッファを確保
     '.lpstrInitialDir = CurDir             'デフォルトのディレクトリを設定
  End With
    
      Ret = GetOpenFileNamePreview(OFN)

   If Ret = 0 Then
      OpenPreviewDlg = vbNullString
   Else
      OpenPreviewDlg = OFN.lpstrFile        'パスを取得
   End If

End Function

APIの呼び出し

[OpenDlgPw.frm]

Private Sub Command1_Click()

Dim nFilter As String
Dim Ret As String

 Text1.Text = ""

'フィルターの設定
 nFilter = "WAVEファイル(*.wav)" & Chr(0) & "*.wav" & Chr(0) & _
           "MIDIファイル(*.mid)" & Chr(0) & "*.mid" & Chr(0) & _
           "AVIファイル(*.avi)" & Chr(0) & "*.avi" & Chr(0) & _
           "AVIファイル(*.avi)" & Chr(0) & "*.*" & Chr(0)

 Ret = OpenPreviewDlg(Form1.hWnd, nFilter)
     
 Text1.Text = Ret
  
End Sub

Private Sub Form_Load()
  Text1.Text = ""
End Sub

ソースコード一式のダウンロード

vbapi_opendlgpw.zip 2.96 KB (3,041 バイト)

このサンプルの動作環境について

このサンプルは 「Windows98」及び「Microsoft Visual Basic 5.0 Professional Edition」で確認しております。環境が異なる場合は正常に動作しない場合もございますのでご了承下さい。





掲示板

ソフトウェア、ハードウェアのプログラミング用の掲示板を作成しました。質問やわからない事は@掲示板でユーザー同士で情報を共有して下さい。

関連記事



公開日:2015年03月03日
記事NO:00325