ホーム > カテゴリ > Visual Basic >

「ファイルを開く」ダイアログを表示する

「ファイルを開く」ダイアログを表示するサンプルです。

サンプルの実行画面

APIの宣言

[OpenDlg.bas]

'------------------------------------------------
'「ファイルを開く」コモンダイヤログを表示するAPI関数
'------------------------------------------------
'<引数>   pOpenfilename:OPENFILENAME構造体
'<戻り値>  OKボタンを押した時1、キャンセルボタンを押した時0

Public Declare Function GetOpenFileName Lib "comdlg32.dll" Alias "GetOpenFileNameA" (pOpenfilename As OPENFILENAME) As Long

'OPENFILENAME構造体
Public Type OPENFILENAME
    lStructSize As Long             '構造体のサイズ
    hwndOwner As Long               'ウインドウのハンドル
    hInstance As Long               'インスタンスハンドル
    lpstrFilter As String           'フィルター
    lpstrCustomFilter As String     'カスタムフィルター
    nMaxCustFilter As Long          'カスタムフィルターのサイズ
    nFilterIndex As Long            'フィルタのインデックス
    lpstrFile As String             'ファイル名のバッファ
    nMaxFile As Long                'ファイル名のバッファのサイズ
    lpstrFileTitle As String        'フルパス用のバッファ
    nMaxFileTitle As Long           'フルパス用のバッファのサイズ
    lpstrInitialDir As String       'ディレクトリを指定
    lpstrTitle As String            'ダイヤログボックスのタイトル
    flags As Long                   '定数(OFN_××参照)
    nFileOffset As Integer          'フルパスの中のファイル名までのオフセット
    nFileExtension As Integer       '拡張子までのオフセット
    lpstrDefExt As String           'デフォルトの拡張子
    lCustData As Long               'lpfnHookで渡すデータ
    lpfnHook As Long                'フック関数のポインタ
    lpTemplateName As String        'テンプレート名
End Type


Public Const OFN_ALLOWMULTISELECT = &H200       '複数ファイルを選択可能にする
Public Const OFN_CREATEPROMPT = &H2000          '指定のファイル名が存在しない時にメッセージボックスを表示
Public Const OFN_FILEMUSTEXIST = &H1000         '存在しないファイル名は入力不可
Public Const OFN_HIDEREADONLY = &H4             '読み取り専用のチェックボックスを非表示
Public Const OFN_NOCHANGEDIR = &H8              '他のサブディレクトリから選択不可
Public Const OFN_NOREADONLYRETURN = &H8000      '読み込み専用ファイルと書きこみ禁止ディレクトリの選択不可
Public Const OFN_NOVALIDATE = &H100             'ファイル名の有効性をチェックしない
Public Const OFN_OVERWRITEPROMPT = &H2          '既存のファイル名を指定した時にメッセージを出す
Public Const OFN_PATHMUSTEXIST = &H800          '有効なパスだけをうけつける
Public Const OFN_READONLY = &H1                 '読み取り専用のチェックボックスをチェック
Public Const OFN_SHOWHELP = &H10                'ヘルプボタンを表示
        
'-----------------------------------------------------------------------------------
'■関数名       OpenDlg
'■用途        「ファイルを開く」コモンダイヤログを表示する
'■引数         nHandle:ウインドウのハンドル、nFilter:フィルター
'■戻り値       ファイルを選択した場合そのファイルのパス名、キャンセルを押した場合""が戻る
'-----------------------------------------------------------------------------------
Public Function OpenDlg(nHandle As Long, nFilter As String) As String

Dim OFN As OPENFILENAME                     'OPENFILENAME構造体
Dim Ret As Long                             '戻り値

   With OFN                                 '構造体の設定
     .flags = OFN_PATHMUSTEXIST Or _
              OFN_FILEMUSTEXIST Or _
              OFN_HIDEREADONLY
              'Or OFN_SHOWHELP
     .hInstance = App.hInstance             'インスタンスハンドルを設定
     .hwndOwner = nHandle                   'ウインドウハンドルを設定
     .lpstrTitle = "ファイルを開く"          'コモンダイアログのタイトルを設定
     .lpstrFilter = nFilter                 'フィルターを設定
     .lStructSize = Len(OFN)                '構造体のサイズを設定
     .nMaxFile = 250                        'ファイル名のバッファのサイズを設定
     .lpstrFileTitle = String(250, Chr(0))  'フルパス用のバッファを確保
     .nMaxFileTitle = 250                   'フルパス用のバッファのサイズを設定
     .lpstrFile = String(250, Chr(0))       'ファイル名のバッファを確保
    '.lpstrInitialDir = CurDir              'デフォルトのディレクトリを指定
   End With
    
    Ret = GetOpenFileName(OFN)

    If Ret = 0 Then                         'キャンセルを押した時の処理
      OpenDlg = vbNullString
    Else                                    'OK押した時の処理
      OpenDlg = OFN.lpstrFile
    End If

End Function

APIの呼び出し

[OpenDlg.frm]

Private Sub Command1_Click()

Dim nFilter As String
Dim Ret As String
Dim ReadData As String

 Text1.Text = ""

'フィルターの設定
 nFilter = "HTMLファイル(*.html,*.htm)" & Chr(0) & "*.html;*.htm" & Chr(0) & _
           "テキストファイル(*.txt)" & Chr(0) & "*.txt" & Chr(0)

 Ret = OpenDlg(Form1.hWnd, nFilter)
     
 Text1.Text = Ret
   
'ファイルを読み込む
 On Error GoTo error:
   
  Open Ret For Input As #1
    Do Until EOF(1)
      Line Input #1, Temp
         ReadData = ReadData & Temp & Chr$(13) & Chr$(10)
      Loop
    Close #1
      
  Text2.Text = ReadData
error: Exit Sub
   
   
End Sub

Private Sub Form_Load()
  Text1.Text = ""
  Text2.Text = "右上のボタンを押して、HTMLファイルかテキストファイルを開いてください。"
End Sub

ソースコード一式のダウンロード

vbapi_opendlg.zip 3.11 KB (3,193 バイト)

このサンプルの動作環境について

このサンプルは 「Windows98」及び「Microsoft Visual Basic 5.0 Professional Edition」で確認しております。環境が異なる場合は正常に動作しない場合もございますのでご了承下さい。





関連記事



公開日:2015年03月03日
記事NO:00324