ホーム > カテゴリ > 画像処理工学 >

濃度抽出(メディアン - 最小濃度抽出)のサンプルコード

画像に「濃度抽出(メディアン - 最小濃度抽出)」の処理をするサンプルです。ソースコードはDelphi5で作成しましたがその他の言語でも流用できるかと思います。

画像処理の結果

濃度抽出(メディアン - 最小濃度抽出)をすると下図のようになります。

ソースコード

[EffectBass.pas - 汎用モジュール]

//Bass Unit
unit EffectBass;

interface
uses
 Windows,SysUtils, Classes, Graphics;

type
 //24bitアクセス用ポインタ
 pRGBarray  = ^TRGBarray;
 TRGBarray  = array[0..0] of TRGBTriple; //None リテラル

type
 //24bitアクセス用ダブルポインタ
 PPBits = ^TPBits;
 TPBits = array[0..0] of pRGBarray; //None リテラル

//汎用プロシージャ
procedure Set24bit(Src,Dest :TBitmap);
function  Set255(Value : integer) : BYTE;

implementation


/////////
procedure Set24bit(Src,Dest :Tbitmap);
begin
  Src.PixelFormat :=pf24bit;
  Dest.PixelFormat:=pf24bit;
  Dest.Width:=Src.Width;
  Dest.Height:=Src.Height;
end;

/////////
function Set255(Value:Integer):Byte;
begin
 if Value>=255 then
  Result:=255
 else if Value<=0 then
 Result:=0
 else Result:=Value;
end;
end.

[濃度抽出(メディアン - 最小濃度抽出)の関数]

//-----------------------------------------------------------------------------
//■関数     EffectMedian_Minimum
//■用途     メディアン(最小濃度抽出)
//■引数     hBMP  ...転送元のビットマップのハンドル
//■戻り値
//           新しいビットマップのハンドル
//-----------------------------------------------------------------------------
function EffectMedian_Minimum(hBMP: HBitmap):HBitmap;
var
  Row,Col,yRow,xCol,x,y: Integer;
  DestRow       : pRGBArray;
  SrcBitmap,DestBitmap : TBitmap;
  SourceRows           : PPBits ;
  rMin,gMin,bMin : Byte;
begin

  SrcBitmap   := TBitmap.Create;
  DestBitmap  := TBitmap.Create;
  SrcBitmap.Handle  := hBMP;
  Set24bit(SrcBitmap,DestBitmap);

  GetMem(SourceRows, SrcBitmap.Height * SizeOf(pRGBArray));
  try

    for Row := 0 to SrcBitmap.Height - 1 do  SourceRows[Row] := SrcBitmap.Scanline[Row];

    for Row := 0 To SrcBitmap.Height-1 do
    begin
         DestRow := DestBitmap.ScanLine[Row];
         for Col := 0 To SrcBitmap.Width-1 do
         begin
             //-------------
             // 0 - 1 - 2
             //-------------
             // 3 - 4 - 5
             //-------------
             // 6 - 7 - 8

             rMin:=255; gMin:=255; bMin:=255;
             
             for y:= -1 to 1 do
             begin
               for x:= -1 to 1 do
               begin
                  // Y軸
                  if  (Row+ y ) > SrcBitmap.Height-1 then  yRow:=SrcBitmap.Height-1
                  else if Row+(y)< 0                 then  yRow:=0
                  else                                     yRow:=Row+(y);
                   // X軸
                  if      Col+(x)> SrcBitmap.Width-1 then  xCol:=SrcBitmap.Width-1
                  else if Col+(x)< 0                 then  xCol:=0
                  else                                     xCol:=Col+(x);

                  // 着目するピクセルで一番小さい濃度値を取得
                  if SourceRows[yRow][xCol].rgbtBlue < bMin then
                    bMin := SourceRows[yRow][xCol].rgbtBlue;

                  if SourceRows[yRow][xCol].rgbtGreen < gMin then
                    gMin := SourceRows[yRow][xCol].rgbtGreen;

                  if SourceRows[yRow][xCol].rgbtRed < rMin then
                   rMin := SourceRows[yRow][xCol].rgbtRed;
               end;
            end;
            DestRow[Col].rgbtRed   :=rMin;
            DestRow[Col].rgbtGreen :=gMin;
            DestRow[Col].rgbtBlue  :=bMin;
         end;           
    end;
                  
    FreeMem(SourceRows); SourceRows:=nil;
    Result := DestBitmap.ReleaseHandle;
  except
     if Assigned(SourceRows) then FreeMem(SourceRows);
     Result := SrcBitmap.ReleaseHandle;
  end;
  SrcBitmap.Free ;
  DestBitmap.Free;
end;

[関数の呼び出し]

procedure TForm1.Button1Click(Sender: TObject);
begin
    Image1.Picture.Bitmap.Handle :=
      EffectMedian_Minimum(Image1.Picture.Bitmap.ReleaseHandle);
end;





関連記事


前の記事：ノーマライズ(ヒストグラムの引き伸ばし)のサンプルコード
次の記事：濃度抽出(メディアン - 中間濃度抽出)のサンプルコード

公開日：2015年02月24日
記事NO：00281