数字を連番で表示するには？

解決

ひひ 2005-05-27 13:54:01 No: 122012

テキストボックスを二つ用意して、一個目に１、二個目に１０といれ、リストボックスに１から１０までの１０個の数字を表示させるにはどうしたらいいですか？

特攻隊長まるるう 2005-05-27 14:21:00 No: 122013

[VB6.0]
Option Explicit

Private Sub Command1_Click()
    Dim wStartCnt As Integer
    Dim wTempCnt As Integer
    Dim wEndCnt As Integer
    If ErrChkText(Me.Text1) Then Exit Sub
    If ErrChkText(Me.Text2) Then Exit Sub
    wStartCnt = CInt(Me.Text1.Text)
    wEndCnt = CInt(Me.Text2.Text)
    If wStartCnt > wEndCnt Then
        wTempCnt = wStartCnt
        wStartCnt = wEndCnt
        wEndCnt = wTempCnt
    End If
    With Me.List1
        .Clear
        For wTempCnt = wStartCnt To wEndCnt
            .AddItem CStr(wTempCnt)
        Next
    End With
End Sub

Private Function ErrChkText(ByVal TextBoxX As TextBox) As Boolean
    Dim TextX As String
    With TextBoxX
        TextX = Trim(.Text)
        If Len(TextX) = 0 Then
            MsgBox .Name & " を入力して下さい。"
            .SetFocus
            ErrChkText = True
            Exit Function
        ElseIf Not IsNumeric(TextX) Then
            MsgBox "数値として有効な値を入力して下さい。"
            .SetFocus
            ErrChkText = True
            Exit Function
        End If
        .Text = CStr(CInt(TextX))
    End With
End Function

ひひ 2005-05-27 16:06:26 No: 122014

完璧でした！ありがとうございます。

ひひ 2005-05-27 17:16:14 No: 122015

完璧でした！ありがとうございます。