リストファイルボックスにドラッグ＆ドロップするには？

解決

hide_s 2003-12-26 01:10:15 No: 110953

リストファイルボックスからファイル名をドラッグ＆ドロップできることは
確認できたのですが、反対にリストファイルボックスに別のディレクトリから
ファイル名をドラッグ＆ドロップすることは可能でしょうか？ご存知の方が
いらっしゃればご教授願います。

かな 2003-12-26 02:17:28 No: 110954

調べてみました。出来るっぽいです。

form1 file1を作って以下を貼り付け。
file1.OLEDropMode を１にする。

Private Sub File1_OLEDragDrop(Data As DataObject, Effect As Long, Button As Integer, Shift As Integer, X As Single, Y As Single)
Dim i As Integer
Dim strTempname As String
    If Data.Files.Count >= 1 Then
        For i = 1 To Data.Files.Count
            strTempname = Dir$(Data.Files(i))
            If Len(strTempname) Then
                FileCopy Data.Files(i), myPathCheck(File1.Path) & strTempname
            End If
        Next i
    End If
    File1.Refresh
    Me.Refresh
End Sub

Private Sub Form_Load()
File1.Path = App.Path
End Sub

Private Function myPathCheck(myPathname As String) As String
    Select Case Len(myPathname)
        Case 0
            myPathCheck = ""
        Case Else
            myPathCheck = myPathname
            If Right$(myPathname, 1) <> "\" Then
                myPathCheck = myPathname & "\"
            End If
    End Select
End Function

こんな感じでチェック関連を入れればいいかなと思います。

hide_s 2003-12-26 02:45:10 No: 110955

>かな様
ご返答ありがとうございます。
早速実行してみます。

hide_s 2003-12-26 02:59:33 No: 110956

>かな様
当方作成のソースに組み込んでテストした結果、希望通りの動きを
することを確認しました。
ご教授頂き非常に助かりました。ありがとうございました。