ループ表示について

解決

初心者 2003-11-21 01:46:13 No: 110106

イベントスタートで"写真1"-"写真2"-"写真3-"写真4"と4つのイメージを順次表示させたいと思います。1イメージ2秒弱で設定してイベントストップまで表示ループし続けさせる文法に付いて教えて下さい。

特攻隊長まるるう 2003-11-21 03:15:40 No: 110107

イベントってボタン押下とか？
継続するためにグローバル変数でフラグを１個用意して、
フラグが変更されるまでタイマーで２秒数えて写真を順に表示…。
イベントストップでフラグ変更。

初心者 2003-11-21 03:50:10 No: 110108

簡単な例サンプルに記述をご指導頂けませんでしょうか？

特攻隊長まるるう 2003-11-21 04:00:30 No: 110109

まずは自分である程度作ってくださいよぉ(ー人ー)

どの程度の知識が合ってどこでつまずいてるのか、最初の質問だけでは
範囲が広いんですよ。タイマーをフォームに貼り付けてぇ…Timer1_Timer
イベントでぇ…とかから説明したくはないです(；▽；)しくしく…

ねろ 2003-11-24 04:37:58 No: 110110

まず表示したいイメージをプログラムと同じフォルダーに入れ
"1.jpg","2.jpg","3.jpg","4.jpg"とする(bmpでもOK)
フォームにImage1を貼り付けプロパティのindexを0とする
次にタイマーとコマンドボタンを貼り付ける
Option Explicit
Private Sub Form_Load()
    Dim n As Integer
    Image1(0).Visible = False
    Timer1.Enabled = False
    Timer1.Interval = 2000 '２秒にセット
    Command1.Caption = "Image Start"
    For n = 1 To 3: Load Image1(n): Next
    For n = 0 To 3
       Image1(n).Picture = LoadPicture(App.Path + "\" + CStr(n + 1) + ".jpg")
    Next
End Sub
Private Sub Command1_Click()
    Dim n As Integer
    If Timer1.Enabled = False Then
       Command1.Caption = "Image Stop"
       Timer1.Enabled = True
       Image1(0).Visible = True
       Command1.Caption = "Image Stop"
    Else
        Command1.Caption = "Image Strat"
        Timer1.Enabled = False
        For n = 0 To 3: Image1(n).Visible = False: Next
    End If
End Sub
Private Sub Timer1_Timer()
    Dim n As Integer
    For n = 0 To 3
        If Image1(n).Visible = True Then
           Image1(n).Visible = False
            If n < 3 Then
                Image1(n + 1).Visible = True
            Else
               Image1(0).Visible = True
            End If
            Exit For
        End If
    Next
End Sub
こんなところでひとつ。

初心者 2003-11-27 03:35:32 No: 110111

感謝感激!!

初心者 2003-11-27 03:36:51 No: 110112

おかげさまで解決