フォルダーの新規作成はわかりますが、
CSVファイルを新規作成するにはどうしたら良いのでしょう。
open 保存ファイル名 for output as #1
for i = 1 to データ総数
write #1 配列（1,i),配列(2,i)....
next i
close #1
みたいな感じで保存が必要なときに書出したのでよいのでは？
ＣＳＶ形式は、項目がカンマ[,]で囲まれていればいいみたいです
"項目","項目",
ファイルを新規作成する方法は２種類あります。
OPEN ステートメントを使う方法と
ファイルシステムオブジェクトを使う方法があります。
一応 ２種類とも書いときます。(好きなほうを使ってください)
OPEN ステートメントを使う方法
Dim intFileNo As Integer
Dim intIndex As Integer
' 空いているファイル番号を取得
intFileNo = FreeFile
' ファイルをシーケンシャル出力モード (Output) で開きます。
Open "C:\test.csv" For Output Access Write As #intFileNo
For intIndex = 0 To 10
' 1行 出力
Print #intFileNo, intIndex & "," & intIndex
Next intIndex
' ファイルを閉じる
Close #intFileNo
ファイルシステムオブジェクトを使う方法
Dim objFileSystem As Object
Dim objFile As Object
Dim strFileName As String
Dim intIndex As Integer
' 作成するファイル名
strFileName = "C:\TEST.csv"
' ファイルシステムオブジェクトへの参照
Set objFileSystem = CreateObject("Scripting.FileSystemObject")
' 作成するファイル名
Set objFile = objFileSystem.CreateTextFile(strFileName)
For intIndex = 0 To 10
' 1行 出力
objFile.WriteLine intIndex & "," & intIndex
Next intIndex
' ファイルを閉じる
objFile.Close
' オブジェクトを解放
Set objFileSystem = Nothing
Set objFile = Nothing
ヘルプを見れば、使用例も載っているので
是非見てください。
あらかじめ—データベースに保存して場合はＳＱＬを使う事もＯＫです
dim Db as database
dim strSql as string
kill app.path & "保存する名前.csv"
strSql = "select* into[保存する名前.csv] " &_
" in '" & app.path & "' 'text;'" & " from titles;"
db.execute strSql
db.close
set db =nothing
CommaSeparatedValueは名前のとおり、項目がカンマで区切られた形式ですが、
その他に、
改行によって、表？の行が区別されますし、
項目自体にカンマが含まれている場合は、区切りのカンマと区別がつかないのでその項目をダブルクォーテーション（"項目"）で囲んであげます。
そして更に、項目に"が含まれている場合は""としつつ、項目をカンマのときと同じように"で囲んであげます。
従って、項目の中に,や"が出てきたときは項目を"で囲んであげることと、項目に"が出てきたときは""に置き換えてあげることが必要です。
Microsoft ExcelのCSV形式でのファイル保存から独学しただけなので、間違っ1ていたらすみません。