コマンドプロンプトにログを出力するには？ (ID:91048)

名前

ホームページ(ブログ、Twitterなど)のURL (省略可)

本文

コマンドプロントじゃなくて、徒のコンソールだけど…

-ConsoleOut.cls-
Option Explicit

Private Declare Function AllocConsole Lib "kernel32" () As Long
Private Declare Function FreeConsole Lib "kernel32" () As Long
Private Declare Function GetStdHandle Lib "kernel32" (ByVal nStdHandle As Long) As Long
Private Declare Function WriteConsole Lib "kernel32" Alias "WriteConsoleA" ( _
        ByVal hConsoleOutput As Long, _
        lpBuffer As Any, _
        ByVal nNumberOfCharsToWrite As Long, _
        lpNumberOfCharsWritten As Long, _
        lpReserved As Any) As Long
        
Private Const STD_OUTPUT_HANDLE = -11&

Private hOut        As Long

Private Function ssb(ByRef s As String) As Byte()
    '(String->to FromUnicode)->byte()
    ssb = StrConv(s, vbFromUnicode)
End Function

Private Sub Class_Initialize()
    'コンソールを開いて、stdOutを得る
    Call FreeConsole
    Call AllocConsole
    hOut = GetStdHandle(STD_OUTPUT_HANDLE)
End Sub

Private Sub Class_Terminate()
    'コンソールを閉じる
    Call FreeConsole
End Sub

Public Function PrintString(ByVal s As String) As Long
    'コンソールに書き込む
    Dim buf()       As Byte
    Dim i           As Long
    
    If s = "" Then Exit Function
    buf = ssb(s)
    i = UBound(buf) - LBound(buf) + 1
    WriteConsole hOut, buf(LBound(buf)), i, PrintString, ByVal 0
End Function

※動くかな…？
  というより、目的に適ってるかな？？
  コマンドプロントを起動して、何かアプリを走らせた状態の標準入出力は、
  …昔サンプルをいただいたのですが、未だに理解が遠い状態(ぇ

←解決時は質問者本人がここをチェックしてください。

戻る