グラフのリアルタイム表示は？・２ (ID:86530)

名前

ホームページ(ブログ、Twitterなど)のURL (省略可)

本文

>ねろさん
くりゅうさんに誤解を与えそうだったので、
勝手ながら、補足させていただきました。
私の考えとは異なる部分もありますが、
仕様がハッキリしてませんし、
どちらをよしとするかはくりゅうさん次第ですね。

ところで、よくドラマなどで見かける心電図風に波形描画サンプルを作成してみました。
ポイントは残像です。
#フォームにピクチャーボックス、コマンドボタン、タイマーを設置。
#ピクチャーボックス内にLineコントロールを設置。
#LineコントロールのIndexプロパティを0に設定。
Dim X                As Long
Dim OLD_Y            As Long
Const TTT            As Long = 75
Const XXX            As Long = 750   
Const Haba           As Long = 7500

Private Sub Command1_Click()
    Timer1 = Not Timer1
End Sub

Private Sub Form_Load()
    
    Me.Width = Haba + 365         
    Me.Height = 6720
    
    With Me.Picture1
        .Width = Haba
        .Height = 5250
        .Left = 120
        .Top = 240
        .BackColor = &H4000&
        .ForeColor = &HFF00&
        .AutoRedraw = True
        .DrawWidth = 6
    End With
    
    Randomize
    Call SCALE_DRAW                              '目盛を描画
    Me.Timer1.Interval = 100
End Sub

Sub SCALE_DRAW()
    Dim i As Long

Line1(0).BorderColor = RGB(50, 100, 50)
    For i = 1 To 11
        Load Line1(i)
        Line1(i).Visible = True
    Next i
    
    For i = 0 To 8
        Line1(i).X1 = XXX + i * XXX
        Line1(i).X2 = XXX + i * XXX
        Line1(i).Y1 = 0
        Line1(i).Y2 = 5250
    Next i
    For i = 9 To 11
        Line1(i).X1 = 0
        Line1(i).X2 = Haba
        Line1(i).Y1 = (5250 \ 4) * (i - 8)
        Line1(i).Y2 = (5250 \ 4) * (i - 8)
    Next i
    
End Sub

Private Sub Timer1_Timer()

Dim Y           As Long
Dim i           As Long
    With Picture1
        '残像
        .DrawMode = 9
        .ForeColor = &H404040
        If X = TTT * 10 Then
            Picture1.Line (Haba - XXX * 2, 0)-(Haba - XXX, 5500), , BF
            .DrawMode = 3
            .ForeColor = &H808080
            Picture1.Line (X, 0)-(X - XXX, 5500), , BF
            .ForeColor = &HB0B0B0
            Picture1.Line (Haba - XXX, 0)-(Haba, 5500), , BF
        ElseIf X = TTT * 20 Then
            Picture1.Line (Haba - XXX, 0)-(Haba, 5500), , BF
            .DrawMode = 3
            .ForeColor = &H808080
            Picture1.Line (X, 0)-(X - XXX, 5500), , BF
            .ForeColor = &HB0B0B0
            Picture1.Line (X - XXX, 0)-(X - XXX * 2, 5500), , BF
        Else
            Picture1.Line (X - XXX * 2, 0)-(X - XXX * 3, 5500), , BF
            .DrawMode = 3
            .ForeColor = &H808080
            Picture1.Line (X, 0)-(X - XXX, 5500), , BF
            .ForeColor = &HB0B0B0
            Picture1.Line (X - XXX, 0)-(X - XXX * 2, 5500), , BF
            If X = Haba Then X = 0
        End If
        
        '波形
        .DrawMode = 13
        .ForeColor = &HFF00&
        For i = 1 To 10
            Y = Int(Rnd * 5000)
            Picture1.Line (X, OLD_Y)-(X + TTT, Y)
            X = X + TTT
            OLD_Y = Y
        Next i
    End With

End Sub

←解決時は質問者本人がここをチェックしてください。

戻る