インターネット上の画像をファイルとして保存せずにピクチャーボックスに表示するには？ (ID:118047)

名前

ホームページ(ブログ、Twitterなど)のURL (省略可)

本文

OleLoadPicturePathとか。
こんなん↓

Option Explicit

Private Type TGUID
    Data1 As Long
    Data2 As Integer
    Data3 As Integer
    Data4(0 To 7) As Byte
End Type

Private Declare Function OleLoadPicturePath Lib _
    "oleaut32.dll" _
    (ByVal szURLorPath As Long, ByVal punkCaller As Long, ByVal dwReserved As Long, _
     ByVal clrReserved As OLE_COLOR, ByRef riid As TGUID, ByRef ppvRet As IPicture) _
        As Long

Private Function LoadURLPicture(ByVal sURL As String) As Picture
    Dim IID  As TGUID
    
    'TGUIDの設定
    With IID
        .Data1 = &H7BF80980
        .Data2 = &HBF32
        .Data3 = &H101A
        .Data4(0) = &H8B
        .Data4(1) = &HBB
        .Data4(2) = &H0
        .Data4(3) = &HAA
        .Data4(4) = &H0
        .Data4(5) = &H30
        .Data4(6) = &HC
        .Data4(7) = &HAB
    End With
    
    On Error GoTo ERR_LINE
    
    Call OleLoadPicturePath(StrPtr(sURL), 0&, 0&, 0&, IID, LoadURLPicture)
    
    Exit Function
    
ERR_LINE:
    
    On Error Resume Next
    
    Set LoadURLPicture = LoadPicture(sURL)
    
    On Error GoTo 0
End Function

Private Sub Command1_Click()
    
    Set Picture1.Picture = LoadURLPicture("http://www.google.co.jp/intl/ja_jp/images/logo.gif")
End Sub

←解決時は質問者本人がここをチェックしてください。

戻る