InputQueryについて (ID:26600)

名前

ホームページ(ブログ、Twitterなど)のURL (省略可)

本文

①・・・
Controls.Pasに以下の関数があると思います。
function InputQuery(const ACaption, APrompt: string;
  var Value: string): Boolean;
var
  ・・・
begin
  ・・・
end;
この関数を新規作成したユニットにコピーします。
説明するの面倒だからこんな感じ
//-----------------------------------------------------
unit Unit1;
interface
uses Windows,Forms,stdCtrls,Graphics,Controls;//追加

function MyInputQuery(const ACaption, APrompt: string; var Value: string): Boolean;//に宣言する。

implementation

function GetAveCharSize(Canvas: TCanvas): TPoint;
var
  I: Integer;
  Buffer: array[0..51] of Char;
begin
  for I := 0 to 25 do Buffer[I] := Chr(I + Ord('A'));
  for I := 0 to 25 do Buffer[I + 26] := Chr(I + Ord('a'));
  GetTextExtentPoint(Canvas.Handle, Buffer, 52, TSize(Result));
  Result.X := Result.X div 52;
end;

//コピペした関数をInputQueryからMyInputQueryに変更した。
function MyInputQuery(const ACaption, APrompt: string;
  var Value: string): Boolean;
var
  Form: TForm;
  Prompt: TLabel;
  Edit: TEdit;
  DialogUnits: TPoint;
  ButtonTop, ButtonWidth, ButtonHeight: Integer;
begin
  Result := False;
  Form := TForm.Create(Application);
  with Form do
    try
      Canvas.Font := Font;
      DialogUnits := GetAveCharSize(Canvas);
      BorderStyle := bsDialog;
      Caption := ACaption;
      ClientWidth := MulDiv(180, DialogUnits.X, 4);
      Position := poScreenCenter;
      Prompt := TLabel.Create(Form);
      with Prompt do
      begin
        Parent := Form;
        Caption := APrompt;
        Left := MulDiv(8, DialogUnits.X, 4);
        Top := MulDiv(8, DialogUnits.Y, 8);
        Constraints.MaxWidth := MulDiv(164, DialogUnits.X, 4);
        WordWrap := True;
      end;
      Edit := TEdit.Create(Form);
      with Edit do
      begin
        Parent := Form;
        Left := Prompt.Left;
        Top := Prompt.Top + Prompt.Height + 5;
        Width := MulDiv(164, DialogUnits.X, 4);
        MaxLength := 255;
        Text := Value;
        SelectAll;
      end;
      ButtonTop := Edit.Top + Edit.Height + 15;
      ButtonWidth := MulDiv(50, DialogUnits.X, 4);
      ButtonHeight := MulDiv(14, DialogUnits.Y, 8);
      with TButton.Create(Form) do
      begin
        Parent := Form;
        Caption := 'OK';//ここと
        ModalResult := mrOk;
        Default := True;
        SetBounds(MulDiv(38, DialogUnits.X, 4), ButtonTop,     ButtonWidth,
          ButtonHeight);
      end;
      with TButton.Create(Form) do
      begin
        Parent := Form;
        Caption := 'Cancel';//ここだけ変更した
        ModalResult := mrCancel;
        Cancel := True;
        SetBounds(MulDiv(92, DialogUnits.X, 4), Edit.Top + Edit.Height + 15,
          ButtonWidth, ButtonHeight);
        Form.ClientHeight := Top + Height + 13;          
      end;
      if ShowModal = mrOk then
      begin
        Value := Edit.Text;
        Result := True;
      end;
    finally
      Form.Free;
    end;
end;
//-------------------------------------------------------

②はこのユニットを共通で使用できるように保存する。
例えば、共有するユニットをプロジェクトとは別に保存しておくフォルダー
を任意に決めておき其のフォルダーにこのユニットを適当な名前で保存しま
す。例えばMyDialogs.pasなど・・・

他のプロジェクトでこの関数を使用したい場合は、「プロジェクト」の「プ
ロジェクトの追加」でこのファイルを指定します。
また、使いたいユニットでは、「ファイル」から「ユニットの追加」でこのユニットを指定することでUses部にユニット名が追加されます
もしくは、自身でUses部にユニット名を記述しても構いません。
(上記の例では MyDialogs )
Uses部に記述すると、そのユニットで記述した関数なりが使用できます。
追加するUses部はこの場合は、interface節でもimplementation節のどちら
でも構いません。
多くの場合は、作成した関数を他のプロジェクトでも使用できるように
こんな感じで作成します。

←解決時は質問者本人がここをチェックしてください。

戻る