指定したフォルダへジャンプするには？ (ID：81665)

名前

ホームページ(ブログ、Twitterなど)のURL (省略可)

本文

モジュールで使用してみてください。
動作していたコードの一部をコピーペーストしました。

Private Declare Function GetOpenFileName Lib "comdlg32.dll" Alias "GetOpenFileNameA" (pOpenfilename As OPENFILENAME) As Long

Private Type OPENFILENAME
    lStructSize       As Long
    hwndOwner         As Long
    hInstance         As Long
    lpstrFilter       As String
    lpstrCustomFilter As String
    nMaxCustFilter    As Long
    nFilterIndex      As Long
    lpstrFile         As String
    nMaxFile          As Long
    lpstrFileTitle    As String
    nMaxFileTitle     As Long
    lpstrInitialDir   As String
    lpstrTitle        As String
    flags             As Long
    nFileOffset       As Integer
    nFileExtension    As Integer
    lpstrDefExt       As String
    lCustData         As Long
    lpfnHook          As Long
    lpTemplateName    As String
End Type

Public Type DIALOGINI
    strTitle       As String        'ダイアログタイトル
    strIniDir      As String        '初期ディレクトリ
    strFilter      As String        'フィルター
    lngFilterIndex As Long          'フィルターのインデックス
    strFilePath    As String        'パス付きファイル名
    strFileName    As String        'ファイル名
    strDefExt      As String
End Type

'**************************************************
'* 関数名   : OpenFileDialog
'* 機  能   : 「ファイルを開く」ダイアログを表示する
'* 引  数   : lngHwnd  ウインドウのハンドル
'*            Dialog   ダイアログ初期設定値
'* 戻り値   : 0以外 正常
'*            0    異常
'* 特記事項 : 複数ファイルを選択できない
'**************************************************
Public Function OpenFileDialog(ByVal lngHwnd As Long, ByRef Dialog As DIALOGINI)

On Error GoTo ErrTrap
    
    Dim OpenFile  As OPENFILENAME       'CommonDialogの構造体
    Dim strFilter As String             'フィルター
    Dim strTemp   As String * 260
    
    strFilter = Replace(Dialog.strFilter, "|", Chr$(0)) & Chr$(0)
    
    'ダイアログの設定
    With OpenFile
        .lStructSize = Len(OpenFile)
        .hwndOwner = lngHwnd
        .lpstrTitle = Dialog.strTitle
        .lpstrInitialDir = Dialog.strIniDir
        .nMaxFile = 260
        .nMaxFileTitle = 260
        .flags = OFN_FILEMUSTEXIST Or OFN_HIDEREADONLY Or OFN_PATHMUSTEXIST
        .lpstrFilter = strFilter
        .nFilterIndex = Dialog.lngFilterIndex
        .lpstrFile = strTemp
        .lpstrFileTitle = strTemp
        .lpstrDefExt = Dialog.strDefExt
    End With
    
    'ダイアログを表示
    OpenFileDialog = GetOpenFileName(OpenFile)
    
    'エラーであれば、プロシージャを抜ける
    If OpenFileDialog = 0 Then
        Exit Function
    End If
    
    Dialog.strFilePath = Left$(OpenFile.lpstrFile, InStrRev(OpenFile.lpstrFile, Chr$(0)) - 1)
    Dialog.strFileName = Left$(OpenFile.lpstrFileTitle, InStrRev(OpenFile.lpstrFileTitle, Chr$(0)) - 1)

Exit Function
    
ErrTrap:
    OpenFileDialog = 0
End Function

←解決時は質問者本人がここをチェックしてください。

戻る