MacOSでMemo帳からGoogle検索をしたい (ID：49346)

名前

ホームページ(ブログ、Twitterなど)のURL (省略可)

本文

このやり方はどうでしょう？
検索文字列の日本語部分はパーセントエンコーディングを行う必要があります。

パーセントエンコーディング
https://ja.wikipedia.org/wiki/%E3%83%91%E3%83%BC%E3%82%BB%E3%83%B3%E3%83%88%E3%82%A8%E3%83%B3%E3%82%B3%E3%83%BC%E3%83%87%E3%82%A3%E3%83%B3%E3%82%B0

下記のコードは、エディットに検索文字列を入れ、検索ボタンを押すとブラウザが開くという単純なコードです。
検索文字列「あいうえお」でもOK。

Macintosh実機で実行させてみましたが、普通に動きました。
手元の環境のMacintoshには、Google Chromeを入れていないので、Safariで起動しますが。

unit MainUnit;

interface

uses
  System.SysUtils, System.Types, System.UITypes, System.Classes, System.Variants,
  FMX.Types, FMX.Controls, FMX.Forms, FMX.Graphics, FMX.Dialogs, FMX.StdCtrls, FMX.Controls.Presentation, FMX.Edit,
  IdURI,
  Macapi.Helpers, Macapi.Foundation, Macapi.AppKit;

type
  TMainForm = class( TForm )
    SearchEdit   : TEdit;
    SearchButton : TButton;
    procedure SearchButtonClick( Sender : TObject );
    procedure OpenBrowser( const AURL : String; const ASearchText : String );
  private
    { private 宣言 }
  public
    { public 宣言 }
  end;

var
  MainForm : TMainForm;

implementation

{$R *.fmx}

// 検索ボタン押下時処理
procedure TMainForm.SearchButtonClick( Sender : TObject );

begin
  OpenBrowser( 'https://www.google.com/search?hl=ja&output=search&q=', SearchEdit.Text );
end;

// ブラウザオープン処理
procedure TMainForm.OpenBrowser( const AURL : String; const ASearchText : String );

var
  WorkSpace : NSWorkspace;
  URL       : NSURL;

begin
  WorkSpace := TNSWorkspace.Wrap( TNSWorkspace.OCClass.sharedWorkspace );
  URL       := TNSURL      .Wrap( TNSURL.OCClass.URLWithString( StrToNSStr( TIdURI.URLEncode( AURL + ASearchText ) ) ) );
  WorkSpace.openURL( URL );
end;

end.

【環境】
・Windows 10 - Delphi 10.2.3 Tokyo
・macOS 10.13.4

←解決時は質問者本人がここをチェックしてください。

戻る