SpinEditのUpClickとDownClick (ID：45518)

名前

ホームページ(ブログ、Twitterなど)のURL (省略可)

本文

もう一つおまけで…
（b）の継承するコードにプロパティをちゃんと実装し、外部のSpinExユニットとして分離

usesにSpinExを追加する。

type
  TForm3 = class(TForm)
    SpinEdit1: TSpinEdit;
    Memo1: TMemo;
    procedure FormCreate(Sender: TObject);
  private
    { Private 宣言 }
    procedure SpinUpClick(Sender: TObject);
    procedure SpinDownClick(Sender: TObject);
  public
    { Public 宣言 }
  end;

var
  Form3: TForm3;

implementation

{$R *.dfm}

procedure TForm3.FormCreate(Sender: TObject);
begin
  SpinEdit1.OnUpClick:=SpinUpClick;
  SpinEdit1.OnDownClick:=SpinDownClick;
end;

procedure TForm3.SpinUpClick(Sender: TObject);
begin
  Memo1.Lines.Add('Up!');
end;

procedure TForm3.SpinDownClick(Sender: TObject);
begin
  Memo1.Lines.Add('Down!');
end;

------------------------------------------------------------------------------------------
// SpinEx.pasユニット

unit SpinEx;

interface

uses
  Classes, Spin;

type
  TSpinEdit = class(Spin.TSpinEdit)
  protected
    procedure UpClick (Sender: TObject); override;
    procedure DownClick (Sender: TObject); override;
  private
    FOnUpClick: TNotifyEvent;
    FOnDownClick: TNotifyEvent;
  public
    property OnUpClick: TNotifyEvent read FOnUpClick write FOnUpClick;
    property OnDownClick: TNotifyEvent read FOnDownClick write FOnDownClick;
  end;

implementation

procedure TSpinEdit.UpClick(Sender: TObject);
begin
  inherited;
  if Assigned(OnUpClick) then OnUpClick(Sender);
end;

procedure TSpinEdit.DownClick(Sender: TObject);
begin
  inherited;
  if Assigned(OnDownClick) then OnDownClick(Sender);
end;

←解決時は質問者本人がここをチェックしてください。

戻る