RitchEdit内容の一部移動をクリップボードを壊さないで行う (ID：14794)

名前

ホームページ(ブログ、Twitterなど)のURL (省略可)

本文

こんなのでどうでしょうか？

uses
  RichEdit;を追加

type
  TEditStreamMode=(esmWrite,esmRead);

TForm1 = class(TForm)
..
  public
    FStreamRec: TEditStream; {←構造体です}
    FStream: TMemoryStream;
  end;
..

implementation

function EditStreamCallBack(dwCookie: Longint; pbBuff: PByte;
    cb: Longint; var pcb: Longint): Longint; stdcall; forward;
{forward 宣言}

//生成と破棄
procedure TForm1.FormCreate(Sender: TObject);
begin
  FStream := TMemoryStream.Create;
  FStreamRec.pfnCallback := @EditStreamCallBack;
end;

procedure TForm1.FormDestroy(Sender: TObject);
begin
  FStream.Free;
end;

//RichTextメモり確保用コールバック関数
function EditStreamCallBack(dwCookie: Longint; pbBuff: PByte;
    cb: Longint; var pcb: Longint): Longint; stdcall;
begin
  try
    case TEditStreamMode(dwCookie) of
      esmWrite: pcb:= Form1.FStream.Write(pbBuff^,cb);
      esmRead : pcb:= Form1.FStream.Read(pbBuff^,cb);

end;
    Result:= 0;
  except
    Result:= 1;

end;
end;

//コピーボタン
procedure TForm1.Button13Click(Sender: TObject);
begin
  FStream.Clear;
  FStreamRec.dwCookie := Longint(esmWrite);
  RichEdit1.Perform( EM_STREAMOUT,SF_RTF or SFF_SELECTION,Longint(@FStreamRec));
end;

//ペーストボタン
procedure TForm1.Button14Click(Sender: TObject);
begin
  FStream.Position:=0;
  FStreamRec.dwCookie := Integer(esmRead);
  RichEdit1.Perform( EM_STREAMIN,SF_RTF or SFF_SELECTION,Longint(@FStreamRec));
end;

←解決時は質問者本人がここをチェックしてください。

戻る