負荷のかけ方 (ID：104762)

名前

ホームページ(ブログ、Twitterなど)のURL (省略可)

本文

負荷を掛けるというのは分かりませんが、
PINGのやり方は、分かるのでカキコします。

まずフォームにテキストボックスとコマンドボタンを用意し、

Option Explicit

Private Sub Command1_Click()
    Dim ECHO            As ICMP_ECHO_REPLY
    Dim lngRet          As Long
    Dim strMsg          As String

DoEvents
    If SocketsInitialize() Then
        lngRet = Ping(Text1.Text, "PingCheck", ECHO)
        SocketsCleanup
        MsgBox lngRet
    Else
        strMsg = "Windows Sockets for 32 bit Windows " & "environments is not successfully responding."
        Call MsgBox(strMsg, vbCritical, "PingError")
    End If
End Sub

標準モジュールに

Option Explicit

Public Const IP_SUCCESS As Long = 0
Public Const IP_STATUS_BASE As Long = 11000
Public Const IP_BUF_TOO_SMALL As Long = (11000 + 1)
Public Const IP_DEST_NET_UNREACHABLE As Long = (11000 + 2)
Public Const IP_DEST_HOST_UNREACHABLE As Long = (11000 + 3)
Public Const IP_DEST_PROT_UNREACHABLE As Long = (11000 + 4)
Public Const IP_DEST_PORT_UNREACHABLE As Long = (11000 + 5)
Public Const IP_NO_RESOURCES As Long = (11000 + 6)
Public Const IP_BAD_OPTION As Long = (11000 + 7)
Public Const IP_HW_ERROR As Long = (11000 + 8)
Public Const IP_PACKET_TOO_BIG As Long = (11000 + 9)
Public Const IP_REQ_TIMED_OUT As Long = (11000 + 10)
Public Const IP_BAD_REQ As Long = (11000 + 11)
Public Const IP_BAD_ROUTE As Long = (11000 + 12)
Public Const IP_TTL_EXPIRED_TRANSIT As Long = (11000 + 13)
Public Const IP_TTL_EXPIRED_REASSEM As Long = (11000 + 14)
Public Const IP_PARAM_PROBLEM As Long = (11000 + 15)
Public Const IP_SOURCE_QUENCH As Long = (11000 + 16)
Public Const IP_OPTION_TOO_BIG As Long = (11000 + 17)
Public Const IP_BAD_DESTINATION As Long = (11000 + 18)
Public Const IP_ADDR_DELETED As Long = (11000 + 19)
Public Const IP_SPEC_MTU_CHANGE As Long = (11000 + 20)
Public Const IP_MTU_CHANGE As Long = (11000 + 21)
Public Const IP_UNLOAD As Long = (11000 + 22)
Public Const IP_ADDR_ADDED As Long = (11000 + 23)
Public Const IP_GENERAL_FAILURE As Long = (11000 + 50)
Public Const MAX_IP_STATUS As Long = (11000 + 50)
Public Const IP_PENDING As Long = (11000 + 255)
Public Const PING_TIMEOUT As Long = 500
Public Const WS_VERSION_REQD As Long = &H101
Public Const MIN_SOCKETS_REQD As Long = 1
Public Const SOCKET_ERROR As Long = -1
Public Const INADDR_NONE As Long = &HFFFFFFFF
Public Const MAX_WSADescription As Long = 256
Public Const MAX_WSASYSStatus As Long = 128

Public Type ICMP_OPTIONS
    Ttl             As Byte
    Tos             As Byte
    Flags           As Byte
    OptionsSize     As Byte
    OptionsData     As Long
End Type

Public Type ICMP_ECHO_REPLY
    Address         As Long
    status          As Long
    RoundTripTime   As Long
    DataSize        As Long 'formerly integer
   'Reserved        As Integer
    DataPointer     As Long
    Options         As ICMP_OPTIONS
    Data            As String * 250
End Type

Public Type WSADATA
    wVersion As Integer
    wHighVersion As Integer
    szDescription(0 To MAX_WSADescription) As Byte
    szSystemStatus(0 To MAX_WSASYSStatus) As Byte
    wMaxSockets As Long
    wMaxUDPDG As Long
    dwVendorInfo As Long
End Type

Public Declare Function IcmpCreateFile Lib "icmp.dll" () As Long

Public Declare Function IcmpCloseHandle Lib "icmp.dll" (ByVal IcmpHandle As Long) As Long

Public Declare Function IcmpSendEcho Lib "icmp.dll" _
    (ByVal IcmpHandle As Long, ByVal DestinationAddress As Long, ByVal RequestData As String, _
    ByVal RequestSize As Long, ByVal RequestOptions As Long, ReplyBuffer As ICMP_ECHO_REPLY, _
    ByVal ReplySize As Long, ByVal Timeout As Long) As Long
    
Public Declare Function WSAGetLastError Lib "WSOCK32.DLL" () As Long

Public Declare Function WSAStartup Lib "WSOCK32.DLL" _
    (ByVal wVersionRequired As Long, lpWSADATA As WSADATA) As Long
    
Public Declare Function WSACleanup Lib "WSOCK32.DLL" () As Long

Public Declare Function gethostname Lib "WSOCK32.DLL" _
    (ByVal szHost As String, ByVal dwHostLen As Long) As Long
    
Public Declare Function gethostbyname Lib "WSOCK32.DLL" (ByVal szHost As String) As Long

Public Declare Sub CopyMemory Lib "kernel32" Alias "RtlMoveMemory" _
    (xDest As Any, xSource As Any, ByVal nbytes As Long)
   
Public Declare Function inet_addr Lib "WSOCK32.DLL" (ByVal s As String) As Long

Public Function GetStatusCode(status As Long) As String

Dim msg As String
    
    Select Case status
        Case IP_SUCCESS:               msg = "ip success"
        Case INADDR_NONE:              msg = "inet_addr: bad IP format"
        Case IP_BUF_TOO_SMALL:         msg = "ip buf too_small"
        Case IP_DEST_NET_UNREACHABLE:  msg = "ip dest net unreachable"
        Case IP_DEST_HOST_UNREACHABLE: msg = "ip dest host unreachable"
        Case IP_DEST_PROT_UNREACHABLE: msg = "ip dest prot unreachable"
        Case IP_DEST_PORT_UNREACHABLE: msg = "ip dest port unreachable"
        Case IP_NO_RESOURCES:          msg = "ip no resources"
        Case IP_BAD_OPTION:            msg = "ip bad option"
        Case IP_HW_ERROR:              msg = "ip hw_error"
        Case IP_PACKET_TOO_BIG:        msg = "ip packet too_big"
        Case IP_REQ_TIMED_OUT:         msg = "ip req timed out"
        Case IP_BAD_REQ:               msg = "ip bad req"
        Case IP_BAD_ROUTE:             msg = "ip bad route"
        Case IP_TTL_EXPIRED_TRANSIT:   msg = "ip ttl expired transit"
        Case IP_TTL_EXPIRED_REASSEM:   msg = "ip ttl expired reassem"
        Case IP_PARAM_PROBLEM:         msg = "ip param_problem"
        Case IP_SOURCE_QUENCH:         msg = "ip source quench"
        Case IP_OPTION_TOO_BIG:        msg = "ip option too_big"
        Case IP_BAD_DESTINATION:       msg = "ip bad destination"
        Case IP_ADDR_DELETED:          msg = "ip addr deleted"
        Case IP_SPEC_MTU_CHANGE:       msg = "ip spec mtu change"
        Case IP_MTU_CHANGE:            msg = "ip mtu_change"
        Case IP_UNLOAD:                msg = "ip unload"
        Case IP_ADDR_ADDED:            msg = "ip addr added"
        Case IP_GENERAL_FAILURE:       msg = "ip general failure"
        Case IP_PENDING:               msg = "ip pending"
        Case PING_TIMEOUT:             msg = "ping timeout"
        Case Else:                     msg = "unknown  msg returned"
    End Select
    GetStatusCode = msg
    
End Function

Public Function Ping(sAddress As String, sDataToSend As String, ECHO As ICMP_ECHO_REPLY) As Long

'If Ping succeeds :
    '.RoundTripTime = time in ms for the ping to complete,
    '.Data is the data returned (NULL terminated)
    '.Address is the Ip address that actually replied
    '.DataSize is the size of the string in .Data
    '.Status will be 0
    '
    'If Ping fails .Status will be the error code
    
    Dim hPort As Long
    Dim dwAddress As Long
    
    'convert the address into a long representation
    dwAddress = inet_addr(sAddress)
    'if a valid address..
    If dwAddress <> INADDR_NONE Then
        'open a port
        hPort = IcmpCreateFile()
        'and if successful,
        If hPort Then
            'ping it.
            Call IcmpSendEcho(hPort, dwAddress, sDataToSend, Len(sDataToSend), 0, ECHO, Len(ECHO), PING_TIMEOUT)
            'return the status as ping succes and close
            Ping = ECHO.status
            Call IcmpCloseHandle(hPort)
        End If
    Else:
        'the address format was probably invalid
        Ping = INADDR_NONE
    End If
    
End Function

Public Sub SocketsCleanup()
    
    If WSACleanup() <> 0 Then
        MsgBox "Windows Sockets error occurred in Cleanup.", vbExclamation
    End If
     
End Sub

Public Function SocketsInitialize() As Boolean
    
    Dim WSAD As WSADATA
    
    SocketsInitialize = WSAStartup(WS_VERSION_REQD, WSAD) = IP_SUCCESS
     
End Function

でOKです。
正常終了  0
異常終了  0以外
テキストボックスにIPを入力してください。

←解決時は質問者本人がここをチェックしてください。

戻る